Private sIniFile  As String

Private Declare Function GetPrivateProfileString _
   Lib "kernel32" Alias "GetPrivateProfileStringA" _
  (ByVal lpSectionName As String, _
   ByVal lpKeyName As Any, _
   ByVal lpDefault As String, _
   ByVal lpbuffurnedString As String, _
   ByVal nBuffSize As Long, _
   ByVal lpFileName As String) As Long
   
Private Declare Function WritePrivateProfileString _
   Lib "kernel32" Alias "WritePrivateProfileStringA" _
  (ByVal lpSectionName As String, _
   ByVal lpKeyName As Any, _
   ByVal lpString As Any, _
   ByVal lpFileName As String) As Long



Private Sub Form_Load()

  'setup
   Text1.Text = "VBnet Demo"
   Text2.Text = "URL1"
   Text3.Text = "http://vbnet.mvps.org/"
   
  'Text4 is used only to display the 
  'contents of the raw file. Editing 
  'the contents of this text box will 
  'have no effect on the demo and will. 
  'Ensure Text4 is set to Multiline.
   Text4.Text = ""
   
   With Command1
      .Caption = "Save Key and Value under Section"
      .Width = 2700
   End With
   
   With Command2
      .Caption = "Save Value of Key under Section"
      .Width = 2700
   End With
   
   With Command3
      .Caption = "Delete Key and Value from INI"
      .Width = 2700
   End With
   
   With Command4
      .Caption = "Delete Entire Section from INI"
      .Width = 2700
   End With
   
  'this will be our test file
   sIniFile = App.Path & "\test.ini"
   
  'show the file contents (empty at first)
   Call LoadIniFile
   
 End Sub


Private Sub Command1_Click()

  'save the the value entered under 
  'the key in the specified section
   Dim sSection As String
   Dim sKeyName As String
   Dim sValue As String
   
   sSection = Text1.Text
   sKeyName = Text2.Text
   sValue = Text3.Text
   
   Call ProfileSaveItem(sSection, sKeyName, sValue, sIniFile)
   
  'refresh the raw file contents 
   LoadIniFile

End Sub


Private Sub Command2_Click()

  'load the value of the specified key 
  'located in sSection 
   Dim sSection As String
   Dim sKeyName As String
   Dim sResult As String
   
   sSection = Text1.Text
   sKeyName = Text2.Text
   Text3.Text = ""
   
   sResult = ProfileGetItem(sSection, _
                            sKeyName, _
                            "oops...data not in file!", _
                            sIniFile)
   
   Text3.Text = sResult
   
   LoadIniFile

End Sub


Private Sub Command3_Click()

  'delete the specified key (and its value)
  'from the specified section
   Dim sSection As String
   Dim sKeyName As String
   
   sSection = Text1.Text
   sKeyName = Text2.Text
   
   Call ProfileDeleteItem(sSection, sKeyName, sIniFile)
   
   LoadIniFile

End Sub


Private Sub Command4_Click()

  'delete the entire section specified
   Dim sSection As String
   
   sSection = Text1.Text
   
   Call ProfileDeleteSection(sSection, sIniFile)
   
   LoadIniFile

End Sub


Private Function ProfileGetItem(sSection As String, _
                                sKeyName As String, _
                                sDefValue As String, _
                                sIniFile As String) As String

  'retrieves a value from an ini file
  'corresponding to the section and
  'key name passed.
        
   Dim dwSize As Long
   Dim nBuffSize As Long
   Dim buff As String
  
  'Call the API with the parameters passed.
  'nBuffSize is the length of the string
  'in buff, including the terminating null.
  'If a default value was passed, and the
  'section or key name are not in the file,
  'that value is returned. If no default
  'value was passed (""), then dwSize
  'will = 0 if not found.
  '
  'pad a string large enough to hold the data
   buff = Space$(2048)
   nBuffSize = Len(buff)
   dwSize = GetPrivateProfileString(sSection, _
                                    sKeyName, _
                                    sDefValue, _
                                    buff, _
                                    nBuffSize, _
                                    sIniFile)
   
   If dwSize > 0 Then
      ProfileGetItem = Left$(buff, dwSize)
   End If
   
End Function


Private Sub ProfileSaveItem(sSection As String, _
                            sKeyName As String, _
                            sValue As String, _
                            sIniFile As String)

  'This function saves the passed value to the file,
  'under the section and key name specified.
  '
  'If the ini file does not exist, it is created.
  'If the section does not exist, it is created within the file.
  'If the key name does not exist, it is created under the section.
  'If the key name exists, it's value is replaced.
   
   Call WritePrivateProfileString(sSection, sKeyName, sValue, sIniFile)

End Sub


Private Sub ProfileDeleteItem(sSection As String, sKeyName As String, sIniFile As String)

  'this call will remove the keyname and its
  'corresponding value from the section sepcified
  'in sSection. This is accomplished by passing
  'vbNullString as the sValue parameter. For example,
  'assuming that an ini file had:
  ' [Colours]
  '  Colour1=Red
  '  Colour2=Blue
  '  Colour3=Green
  '
  'and this sub was called passing "Colour2"
  'as sKeyName, the resulting ini file
  'would contain:
  ' [Colours]
  '  Colour1=Red
  '  Colour3=Green
   
   Call WritePrivateProfileString(sSection, _
                                  sKeyName, _
                                  vbNullString, _
                                  sIniFile)

End Sub


Private Sub ProfileDeleteSection(sSection As String, sIniFile As String)

  'this call will remove the entire section
  'corresponding to sSection in the file.
  'This is accomplished by passing
  'vbNullString as both the sKeyName and
  'sValue parameters. For example, assuming 
  'that an ini file had:
  ' [Colours]
  '  Colour1=Red
  '  Colour2=Blue
  '  Colour3=Green
  '
  'and this sub was called passing "Colours"
  'as sSection, the entire Colours
  'section and all keys and values in 
  'the section would be deleted.
   
   Call WritePrivateProfileString(sSection, _
                                  vbNullString, _
                                  vbNullString, _
                                  sIniFile)

End Sub


Private Sub LoadIniFile()

   Dim hFile As Integer
   
   On Local Error Resume Next

  'obtain the next free file handle
   hFile = FreeFile

  'load the file
   Open sIniFile For Input As #hFile
      Text4.Text = Input$(LOF(hFile), hFile)
   Close #hFile
   
End Sub