Private Type myLong64
   var1 As Long
   var2 As Long
End Type

Private Type SHQUERYRBINFO
   cbSize         As Long
   i64Size        As myLong64
   i64NumItems    As myLong64
End Type

Private Const SW_NORMAL = 1
Private Const SW_SHOWMAXIMIZED = 3
Private Const SW_SHOWDEFAULT = 10
Private Const SW_SHOWNOACTIVATE = 4
Private Const SW_SHOWNORMAL = 1

Private Const HWND_DESKTOP = 0
Private Const SHERB_NOCONFIRMATION = &H1
Private Const SHERB_NOPROGRESSUI = &H2
Private Const SHERB_NOSOUND = &H4

Private Declare Function ShellExecute Lib "shell32" _
    Alias "ShellExecuteA" _
   (ByVal hwnd As Long, _
    ByVal lpOperation As String, _
    ByVal lpFile As String, _
    ByVal lpParameters As String, _
    ByVal lpDirectory As String, _
    ByVal nShowCmd As Long) As Long

Private Declare Function SHQueryRecycleBin Lib "shell32" _
    Alias "SHQueryRecycleBinA" _
   (ByVal pszRootPath As String, _
    pSHQueryRBInfo As SHQUERYRBINFO) As Long

Private Declare Function SHEmptyRecycleBin Lib "shell32" _
    Alias "SHEmptyRecycleBinA" _
   (ByVal hwnd As Long, _
    ByVal pszRootPath As String, _
    ByVal dwFlags As Long) As Long


Private Sub Form_Load

   Command1.Caption = "Open Recycle Bin"
   Command2.Caption = "Explore C"
   Command3.Caption = "Requery Bin Status"
   Command4.Caption = "Empty Recycle Bin"
   Command5.Caption = "Exit"
   
   Check1(0).Caption = "Don't show confirmation dialog"
   Check1(1).Caption = "Don't show progress dialog"
   Check1(2).Caption = "Don't play completion sound"
   
  'get the bin stats by setting
  'the value property of the
  'requery button to true
   Command3.Value = True
   
   
End Sub


Private Sub Command1_Click()
  
   Dim sCommand As String  
   
 'Win95 class ID of the Recycle Bin
   sCommand = "/root,::{645FF040-5081-101B-9F08-00AA002F954E}"
 
  Call ShellExecute(HWND_DESKTOP, _
                    "Open", _
                    "explorer.exe", _
                    sCommand, 0&, _
                    SW_SHOWNORMAL)

End Sub


Private Sub Command2_Click()
  
   Dim sCommand As String  
   
 'Win95 class ID of the Recycle Bin
   sCommand = "/e,c:\"
 
  Call ShellExecute(HWND_DESKTOP, _
                    "Open", _
                    "explorer.exe", _
                    sCommand, 0&, _
                    SW_SHOWNORMAL)

End Sub



Private Sub Command3_Click()

   Dim binCount As Long
   
   binCount = GetBitBucketCount()
   
   If binCount Then
      Label1.Caption = "The Recycle Bin contains " & binCount & " items."
   Else
      Label1.Caption = "The Recycle Bin is empty."
   End If

   Command4.Enabled = binCount > 0

End Sub


Private Sub Command4_Click()

   EmptyBitBucket
   
End Sub


Private Sub Command5_Click()

   Unload Me
   
End Sub


Private Function EmptyBitBucket(Optional drvBin As String)
 
   Dim flags As Long
      
  'if a specific bin is nor passed,
  'then set the drvBin to a null string
  'to perform the action on all bins
   If drvBin = "" Then
      drvBin = vbNullString
   End If
   
  'set the option flags based on the
  'check buttons
   If Check1(0).Value = 1 Then flags = SHERB_NOCONFIRMATION
   If Check1(1).Value = 1 Then flags = flags Or SHERB_NOPROGRESSUI
   If Check1(2).Value = 1 Then flags = flags Or SHERB_NOSOUND
   
  'empty the bin
   Call SHEmptyRecycleBin(Me.hwnd, drvBin, flags)
   DoEvents
  
  'update the stats by setting
  'the value property of the
  'requery button to true
   Command3.Value = True
   
End Function


Private Function GetBitBucketCount() As Long

   Dim SHQBI As SHQUERYRBINFO
 
  'just need to set the length of the structure
   With SHQBI
      .cbSize = LenB(SHQBI)
   End With

   Call SHQueryRecycleBin(vbNullString, SHQBI)

   GetBitBucketCount = (SHQBI.i64NumItems.var1 + SHQBI.i64NumItems.var2)

End Function