'/* Below used for listview column auto-resizing
Private Const LVM_FIRST As Long = &H1000
Private Const LVM_SETCOLUMNWIDTH As Long = (LVM_FIRST + 30)
Private Const LVSCW_AUTOSIZE As Long = -1
Private Const LVSCW_AUTOSIZE_USEHEADER As Long = -2

Private Declare Function SendMessage Lib "user32" _
   Alias "SendMessageA" _
  (ByVal hwnd As Long, _
   ByVal wMsg As Long, _
   ByVal wParam As Long, _
   lParam As Any) As Long


Private Sub Form_Load()

   With ListView1
      .ListItems.Clear
      .ColumnHeaders.Clear
      .ColumnHeaders.Add , , "DeviceID"
      .ColumnHeaders.Add , , "MAC Addr"
      .ColumnHeaders.Add , , "Type"
      .ColumnHeaders.Add , , "Manufacturer"
      .ColumnHeaders.Add , , "Description"
      .View = lvwReport
      .Sorted = False
   End With
        
   Command1.Caption = "Get Adapter Info"

End Sub


Private Sub Command1_Click()

   ListView1.ListItems.Clear
   Call wmiNetAdapterInfo
   Call lvAutosizeControl(ListView1)
   
End Sub


Private Sub lvAutosizeControl(lv As ListView)

   Dim col2adjust As Long

  '/* Size each column based on the maximum of
  '/* EITHER the columnheader text width, or,
  '/* if the items below it are wider, the
  '/* widest list item in the column
   For col2adjust = 0 To lv.ColumnHeaders.Count - 1
   
      Call SendMessage(lv.hwnd, _
                       LVM_SETCOLUMNWIDTH, _
                       col2adjust, _
                       ByVal LVSCW_AUTOSIZE_USEHEADER)

   Next
   
End Sub


Private Sub wmiNetAdapterInfo()

   Dim NetAdapter As SWbemObjectSet
   Dim na As SWbemObject
   Dim itmx As ListItem
     
  'must have error handler enabled, as all
  'adapters do not return all information
   On Local Error Resume Next
   
   Set NetAdapter = GetObject("winmgmts:").InstancesOf("Win32_NetworkAdapter")
   
   For Each na In NetAdapter
   
      Set itmx = ListView1.ListItems.Add(, , na.DeviceID)
      itmx.SubItems(1) = na.MACAddress
      itmx.SubItems(2) = na.AdapterType
      itmx.SubItems(3) = na.Manufacturer
      itmx.SubItems(4) = na.Description
      
   Next
   
End Sub