Private Type LVBKIMAGE
   uFlags As Long
   hBmp As Long
   pszImage As String
   cchImageMax As Long
   xOffsetPercent As Long
   yOffsetPercent  As Long
End Type

Private Type tagINITCOMMONCONTROLSEX
    dwSize As Long
    dwICC As Long
End Type

Private Const ICC_LISTVIEW_CLASSES As Long = &H1
Private Const CLR_NONE = &HFFFFFFFF
Private Const LVM_FIRST As Long = &H1000
Private Const LVBKIF_SOURCE_NONE = &H0
Private Const LVBKIF_SOURCE_HBITMAP = &H1
Private Const LVBKIF_SOURCE_URL = &H2
Private Const LVBKIF_SOURCE_MASK = &H3
Private Const LVBKIF_STYLE_NORMAL = &H0
Private Const LVBKIF_STYLE_TILE = &H10
Private Const LVBKIF_STYLE_MASK = &H10
Private Const LVM_SETBKIMAGEA = (LVM_FIRST + 68)
Private Const LVM_SETBKIMAGEW = (LVM_FIRST + 138)
Private Const LVM_GETBKIMAGEA = (LVM_FIRST + 69)
Private Const LVM_GETBKIMAGEW = (LVM_FIRST + 139)
Private Const LVM_SETBKIMAGE = LVM_SETBKIMAGEA
Private Const LVM_GETBKIMAGE = LVM_GETBKIMAGEA
Private Const LVM_SETTEXTBKCOLOR = (LVM_FIRST + 38)
Private Const LVM_SETEXTENDEDLISTVIEWSTYLE As Long = (LVM_FIRST + 54)
Private Const LVS_EX_FULLROWSELECT As Long = &H20
   
Private Declare Function SendMessage Lib "User32" _
   Alias "SendMessageA" _
  (ByVal hWnd As Long, _
   ByVal wMsg As Long, _
   ByVal wParam As Long, _
   lParam As Any) As Long

Private Declare Sub InitCommonControls Lib "comctl32" ()

Private Declare Function InitCommonControlsEx Lib "comctl32" _
   (lpInitCtrls As tagINITCOMMONCONTROLSEX) As Boolean
   
         

Private Sub Form_Load()

   With ListView1
      .SortKey = 0
      .SmallIcons = ImageList1
      .ColumnHeaders(1).Width = .Width - 600
      .View = lvwReport
   End With
   
   Call InitComctl32(ICC_LISTVIEW_CLASSES)

  'An alternate way to set the extended listview styles!
   Call SendMessage(ListView1.hWnd, _
                    LVM_SETEXTENDEDLISTVIEWSTYLE, _
                    LVS_EX_FULLROWSELECT, ByVal True)
   
   DisplayNoDataImage
      
End Sub


Private Sub Command1_Click()

   Dim BKIMG As LVBKIMAGE
   
  'prepare the backimage structure data
   With BKIMG
      'use the file provided in pszImage member
      .uFlags = LVBKIF_SOURCE_URL
      
      'the imagefile to display
      .pszImage = (Text3.Text)
      
      'h&v offsets for the pix in percent. A setting
      'of 0 aligns the image against the left or top;
      '100 against the right or bottom.  A setting of
      '50 each centers the image in the control.
      .xOffsetPercent = 50
      .yOffsetPercent = 50
  
   End With
   
  'set the text background to none (transparent) to
  'allow image to show through.  A RGB() value can
  'also be passed to colour the text background
  '(to the edge of the control)
   Call SendMessage(ListView1.hWnd, _
                    LVM_SETTEXTBKCOLOR, _
                    0&, ByVal CLR_NONE)
   
  'set the image to the listview
   Call SendMessage(ListView1.hWnd, _
                    LVM_SETBKIMAGE, _
                    0, BKIMG)

End Sub


Private Sub Command2_Click()
   
   BuildLVdata
   DisplayNoDataImage

End Sub


Private Sub Command3_Click()

   Dim BKIMG As LVBKIMAGE
   
  'prepare the backimage structure data
   With BKIMG
      'use the file provided in pszImage and tile
      .uFlags = LVBKIF_SOURCE_URL Or LVBKIF_STYLE_TILE
      
      'the imagefile to display
      .pszImage = (Text2.Text)
      
      'h&v offsets for the pix (only if tiled not specified)
      '.xOffsetPercent = 0
      '.yOffsetPercent = 0
   End With
   
  'set the text background to none (transparent) to
  'allow image to show through.  A RGB() value can
  'also be passed to colour the text background
  '(to the edge of the control)
   Call SendMessage(ListView1.hWnd, _
                    LVM_SETTEXTBKCOLOR, _
                    0&, ByVal CLR_NONE)
   
  'set the image to the listview
   Call SendMessage(ListView1.hWnd, _
                    LVM_SETBKIMAGE, _
                    0&, BKIMG)
   
End Sub


Private Sub Command4_Click()

      ListView1.ListItems.Clear
      DisplayNoDataImage
   
End Sub


Private Sub Command5_Click()

   Unload Me
   
End Sub


Private Sub BuildLVdata()

   Dim itmX As ListItem
   Dim imgX As ListImage
   Dim sItem As String
   Dim c As Integer
   
   For c = 1 To 20
   
      sItem = "Listview listitem #" & c
      Set itmX = ListView1.ListItems.Add(, , Trim$(sItem))
      
      itmX.SmallIcon = ImageList1.ListImages("page").Key
   
   Next
      
End Sub


Private Sub DisplayNoDataImage()

   Dim BKIMG As LVBKIMAGE
   
   With BKIMG
   
      If ListView1.ListItems.Count > 0 Then
     
       'remove the 'no data' image by clearing
       'the image flag
        .uFlags = LVBKIF_SOURCE_NONE
        
      Else
        'set the image to the 'no data text' image
        'Specifying LVBKIF_SOURCE_URL indicates that the 
        'lParam member in SendMessage contains the 
        'path/filename of the image.
        .uFlags = LVBKIF_SOURCE_URL
        .pszImage = (Text1.Text)
        .xOffsetPercent = 3
        .yOffsetPercent = 3
      End If
     
   End With
      
   Call SendMessage(ListView1.hWnd, _
                    LVM_SETTEXTBKCOLOR, _
                    0&, ByVal CLR_NONE)

   Call SendMessage(ListView1.hWnd, _
                    LVM_SETBKIMAGE, _
                    0&, BKIMG)
      
End Sub


Private Function InitComctl32(dwFlags As Long) As Boolean

  Dim icc As tagINITCOMMONCONTROLSEX
  On Error GoTo Err_OldVersion
  
  icc.dwSize = Len(icc)
  icc.dwICC = dwFlags
  
 'VB will generate error 453 "Specified
 'DLL function not found" here if the new
 'version isn't installed and it can't find
 'the function's name. We'll hopefully be
 'able to load the old version below. Note 
 'that the methods here must have comctl32.dll 
 'v4.72 or greater; this routine only 
 'initializes the API; it does not 
 'determine the version.
  InitComctl32 = InitCommonControlsEx(icc)
  Exit Function

Err_OldVersion:
  InitCommonControls

End Function