'change this to a suitable location on your system!
Private Const sTestFile As String = "d:\test.txt"

Private Const OPEN_ALWAYS As Long = 4
Private Const FILE_BEGIN As Long = 0
Private Const GENERIC_WRITE As Long = &H40000000
Private Const GENERIC_READ As Long = &H80000000
Private Const FILE_ATTRIBUTE_NORMAL As Long = &H80

'test file UDT
Private Type TestData
   s1 As String * 15
   s2 As String * 5
   dw1 As Long
   dt1 As Date
   dw2 As Long
   s3 As String * 13
End Type

Private Declare Function CreateFile Lib "kernel32" _
   Alias "CreateFileA" _
  (ByVal lpFileName As String, _
   ByVal dwDesiredAccess As Long, _
   ByVal dwShareMode As Long, _
   ByVal lpSecurityAttributes As Long, _
   ByVal dwCreationDisposition As Long, _
   ByVal dwFlagsAndAttributes As Long, _
   ByVal hTemplateFile As Long) As Long

Private Declare Function GetFileSize Lib "kernel32" _
   (ByVal hfile As Long, lpFileSizeHigh As Long) As Long

Private Declare Function SetFilePointer Lib "kernel32" _
   (ByVal hfile As Long, _
    ByVal lDistanceToMove As Long, _
    lpDistanceToMoveHigh As Long, _
    ByVal dwMoveMethod As Long) As Long

Private Declare Function SetEndOfFile Lib "kernel32" _
  (ByVal hfile As Long) As Long

Private Declare Function CloseHandle Lib "kernel32" _
   (ByVal hfile As Long) As Long



Private Sub Form_Load()

   Command1.Caption = "Create random file"
   Command2.Caption = "Read random file data"
   Command3.Caption = "Delete last random record"

End Sub


Private Sub Command1_Click()

   Dim td As TestData
   Dim nodata As TestData
   Dim cnt As Long
   Dim hfile As Long

   hfile = FreeFile
   Open sTestFile For Random Access Write As #hfile Len = Len(td)

    'add 15 random records to the test file
      For cnt = 1 To 15

         With td
         
           'for debug purposes, this line is
           'the first line of each record written
            .s1 = "begin record " & cnt
            
           'for debug purposes, this line is
           'the last line of each record written
            RSet .s3 = "the end of " & cnt
            
           'some other random data for the record
            .s2 = String(Len(.s1), cnt + 96)
            .dw1 = 1234
            .dw2 = 3445
            .dt1 = Now
         End With
         
         Put #hfile, cnt, td
         
         td = nodata
      Next cnt
      
   Close #hfile
   
   Debug.Print "file created"
   
End Sub


Private Sub Command2_Click()

   Dim td As TestData
   Dim nodata As TestData
   Dim cnt As Long
   Dim hfile As Long
   Dim totalrecords As Long

   hfile = FreeFile
   Open sTestFile For Random Access Read As #hfile Len = Len(td)

      totalrecords = LOF(hfile) \ Len(td)
      
      For cnt = 1 To totalrecords
      
         Get #hfile, cnt, td
         
         With td
            Debug.Print .s1
            Debug.Print .s2
            Debug.Print .dw1
            Debug.Print .dw2
            Debug.Print .dt1
            Debug.Print .s3
         End With
         
         td = nodata
      Next cnt
      
   Close #hfile
   
End Sub


Private Sub Command3_Click()
   
   DeleteLastRandomRecord
   
End Sub


Private Sub DeleteLastRandomRecord()

   Dim td As TestData
   Dim hfile As Long
   Dim totalrecords As Long
   Dim newfilesize As Long
   Dim dwFileSizeLow As Long
   Dim dwFileSizeHigh As Long
      
  'how many records in the file?
   totalrecords = FileLen(sTestFile) \ Len(td)
      
  'can't truncate the file if
  'totalrecords is less than 2
   If totalrecords >= 2 Then
   
     'open the file using the API
      hfile = CreateFile(sTestFile, _
                          GENERIC_WRITE Or GENERIC_READ, _
                          0&, ByVal 0&, _
                          OPEN_ALWAYS, _
                          FILE_ATTRIBUTE_NORMAL, _
                          0&)
                            
     'Get the file size. Note that the value
     'returned is the size of the file as
     'stored in the low word of GetFileSize with
     'the high word returning 0. This will
     'accommodate most reasonably-sized files.
     'If the file is large, however, then the low
     'and high word values have to be be combined
     'to get the actual size. This demo assumes a
     'you're using a reasonably sized random access
     'file, so a test of dwFileSizeHigh is made
     'to ensure it is 0 before truncating.
      dwFileSizeLow = GetFileSize(hfile, dwFileSizeHigh)
      
      If dwFileSizeHigh = 0 Then
         
        'dwFileSizeLow for this test is the
        'file size; one record is Len(td),
        'so in order to delete the last
        'record the new size is the current
        'size minus the length of one record:
         newfilesize = dwFileSizeLow - Len(td)
        
         Debug.Print totalrecords, dwFileSizeLow, newfilesize
         
        'now move the file pointer to the
        'new end position ..
         If SetFilePointer(hfile, newfilesize, dwFileSizeHigh, FILE_BEGIN) > 0 Then
         
           'and "delete" the last record by
           'changing the end of file marker
            Call SetEndOfFile(hfile)
         
         End If  'SetFilePointer
         
      End If  'dwFileSizeHigh

      CloseHandle hfile
   
   End If
   
End Sub