'In the form file's general declarations 
'section, add the following variables:

  'add 2 variables to preventing re-loading of the
  'icons if the same file is chosen, or the apply
  'button is pressed with the same iconset    
   Dim CurrentIconSetFlag As Single
   Dim FileSetLoadedFlag As Single

  'add a variable to hold a keyname for
  'our required 'place holder'.   
   Dim Placeholder As String

'In the form's Form_Load sub, add: 
   
  'set a "blank" dummy icon variable name   
   Placeholder = "dummy" 

'In the form file's cmdLoad sub, comment 
'out the two SavePicture lines (they're not 
'required), then add the following new code
'to the end of the cmdLoad sub, just before
'the first Exit Sub statement:
   
  'To prevent reloading of the imagelist
  'with the icon, set the FileSetLoadedFlag
  'to some numeric variable that will have
  'changed the next time this sub is run. 
  'The value returned by the Now statement
  'works perfectly for this!   
   FileSetLoadedFlag! = Now
   
  'Assure no imagelist error is generated
  'by disabling the buttons if an invalid 
  'handle exists in hImgSmall.    
   Command3.Enabled = hImgSmall <> 0
   Command4.Enabled = hImgSmall <> 0
   Command5.Enabled = hImgSmall <> 0 

'Add the following new code to the form:

Private Sub Command3_Click()

   Dim pnlX As Panel
   Dim imgX As ListImage
   
  'If the icons in the imagelist are 
  'the same icons currently loaded, 
  'then everything's ready to go, 
  'and there's nothing here that needs
  'doing except to redisplay the loaded
  'icon. The flags set here and in the 
  'cmdLoad routine determine which code
  'to execute.   

   Select Case FileSetLoadedFlag! = CurrentIconSetFlag!
      Case True   
        'they match, so just display the icon   
         Set StatusBar1.Panels(1).Picture = _
              ImageList1.ListImages(2).Picture
         StatusBar1.Panels(1).Text = Info1.Caption

      Case Else   
        'Clear the image list and add code to load a
        'blank icon to image position 1 (the Placeholder).  

        'Because the user can change the 
        'colours of 3D objects via the screen
        'properties, it is unsafe to assume 
        'that gray will always be the statusbar
        'colour. This code assures that whatever
        'the user's colour, the "blank" pix will
        'always equal the background colour of
        'the 3D objects (unless, of course, the
        'user changes the 3D colour during 
        'program execution).

        'delete all icons from the imagelist,
        'add a "blank" icon to the first item
        'in the imagelist, and assign the "Placeholder"
        'picture to the first ListImage   
         ImageList1.ListImages.Clear
         pixNone.Picture = pixNone.Image
         Set imgX = ImageList1.ListImages.Add(_
                    1, _
                    Placeholder, _
                    pixNone.Picture)
           
        'realize the pixSmall image and
        'add it to the imagelist   
         pixSmall.Picture = pixSmall.Image
         Set imgX = ImageList1.ListImages.Add(, , _
                    pixSmall.Picture)
           
        'set the new imagelist picture to the statusbar   
         Set StatusBar1.Panels(1).Picture = _
               ImageList1.ListImages(2).Picture
         StatusBar1.Panels(1).Text = Info1.Caption
           
        'save the current Icon to the flag   
        CurrentIconSetFlag! = FileSetLoadedFlag!

    End Select

End Sub 


Private Sub Command4_Click()
   
  'assign the "Placeholder" ListImage 
  'to the first Statusbar panel.   
   Set StatusBar1.Panels(1).Picture = _
         ImageList1.ListImages(Placeholder).Picture

End Sub 


Private Sub Command5_Click()
   
  'delete the icon from 
  'the statusbar control   
   Set StatusBar1.Panels(1).Picture = Nothing

End Sub