Related:  

Windows provides a method - EnumDateFormats - that allows the developer to interrogate the system to retrieve the date formats valid for that system via EnumDateFormatsProc. Where EnumDateFormats is passed the LCID of the system obtained through GetSystemDefaultLCID, the values returned represent formats applicable to the system. When GetUserDefaultLCID is used, the values represent those that may contain customizations to the formats made by the currently logged-on user. GetUserDefaultLCID is defined identically to GetSystemDefaultLCID.

The EnumDateFormatsProc function is an application defined-callback function used with the EnumDateFormats function. It receives a pointer to a string buffer containing a date format string. The DATEFMT_ENUMPROC type defines a pointer to this callback function. EnumDateFormatsProc is a placeholder for the application defined-function name.

The single value returned from the callback - lpDateFormatString - is a pointer to a string buffer containing a null-terminated date format string. This string is a long or short date format, depending on the value of the dwFlags parameter passed to EnumDateFormats. Note that lpDateFormatString should be an LPWSTR for the Unicode (W) version of EnumDateFormats, and an LPSTR for the ANSI (A) version of EnumDateFormats.

The date format strings are translated from Unicode to ANSI, for the ANSI version of this function, based on the default ANSI code page for the LCID. However, if LOCALE_USE_CP_ACP is specified as the dwFlags member, the translation is done using the system default ANSI code page.

Option Explicit

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Copyright ©1996-2011 VBnet/Randy Birch, All Rights Reserved.
' Some pages may also contain other copyrights by the author.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Distribution: You can freely use this code in your own
'               applications, but you may not reproduce 
'               or publish this code on any web site,
'               online service, or distribute as source 
'               on any media without express permission.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

Public Const DATE_LONGDATE As Long = &H2
Public Const DATE_SHORTDATE As Long = &H1
Public Const LOCALE_SLANGUAGE As Long = &H2 'localized name of language
Public Const LOCALE_SSHORTDATE As Long = &H1F 'short date format string
Public Const LOCALE_SLONGDATE As Long = &H20 'long date format string
         
Public Declare Function GetThreadLocale Lib "kernel32" () As Long

Public Declare Function GetSystemDefaultLCID Lib "kernel32" () As Long

Public Declare Function GetLocaleInfo Lib "kernel32" _
   Alias "GetLocaleInfoA" _
  (ByVal Locale As Long, _
   ByVal LCType As Long, _
   ByVal lpLCData As String, _
   ByVal cchData As Long) As Long

Public Declare Function EnumDateFormats Lib "kernel32" _
   Alias "EnumDateFormatsA" _
  (ByVal lpDateFmtEnumProc As Long, _
   ByVal Locale As Long, _
   ByVal dwFlags As Long) As Long

Public Declare Sub CopyMemory Lib "kernel32" _
   Alias "RtlMoveMemory" _
  (Destination As Any, _
   Source As Any, _
   ByVal Length As Long)


Public Function EnumDatesProc(lpDateFormatString As Long) As Long

  'application-defined callback function for EnumDateFormats

   Dim buffer As String
   Dim pos As Integer
   
  'pad a string to hold the format
   buffer = Space$(256)
   
  'copy the string pointed to by the return value
   CopyMemory ByVal buffer, lpDateFormatString, ByVal Len(buffer)
   
  'add to the list
   pos = InStr(buffer, Chr$(0))
   
   If pos Then
      buffer = Left$(buffer, pos - 1)
   End If
   
   Form1.List1.AddItem "   " & buffer
   
  'and return 1 to continue enumeration 
  'until completed (or return 0 to stop)
   EnumDatesProc = 1
   
End Function


Public Function GetUserLocaleInfo(ByVal dwLocaleID As Long, _
                                  ByVal dwLCType As Long) As String

   Dim sReturn As String
   Dim r As Long

  'call the function passing the Locale type
  'variable to retrieve the required size of
  'the string buffer needed
   r = GetLocaleInfo(dwLocaleID, dwLCType, sReturn, Len(sReturn))
    
  'if successful..
   If r Then
    
     'pad the buffer with spaces
      sReturn = Space$(r)
       
     'and call again passing the buffer
      r = GetLocaleInfo(dwLocaleID, dwLCType, sReturn, Len(sReturn))
     
     'if successful (r > 0)
      If r Then
      
        'r holds the size of the string
        'including the terminating null
         GetUserLocaleInfo = Left$(sReturn, r - 1)
      
      End If
   
   End If
    
End Function

In this situation Windows' provides an alternate API you can use to obtain the LCID for the current user ... GetUserDefaultLCID. Defined identically to GetSystemDefaultLCID, GetUserDefaultLCID function retrieves the current user's default–locale identifier, and is therefore the most appropriate API to use when it is the user's locale you are interested in, rather than that of the system.

Copyright ©1996-2011 VBnet and Randy Birch. All Rights Reserved.
Terms of Use  |  Your Privacy