Private Const MAX_ADAPTER_NAME_LENGTH         As Long = 256
Private Const MAX_ADAPTER_DESCRIPTION_LENGTH  As Long = 128
Private Const MAX_ADAPTER_ADDRESS_LENGTH      As Long = 8
Private Const ERROR_SUCCESS  As Long = 0

Private Type IP_ADDRESS_STRING
    IpAddr(0 To 15)  As Byte
End Type

Private Type IP_MASK_STRING
    IpMask(0 To 15)  As Byte
End Type

Private Type IP_ADDR_STRING
    dwNext     As Long
    IpAddress  As IP_ADDRESS_STRING
    IpMask     As IP_MASK_STRING
    dwContext  As Long
End Type

Private Type IP_ADAPTER_INFO
  dwNext                As Long
  ComboIndex            As Long  'reserved
  sAdapterName(0 To (MAX_ADAPTER_NAME_LENGTH + 3))        As Byte
  sDescription(0 To (MAX_ADAPTER_DESCRIPTION_LENGTH + 3)) As Byte
  dwAddressLength       As Long
  sIPAddress(0 To (MAX_ADAPTER_ADDRESS_LENGTH - 1))       As Byte
  dwIndex               As Long
  uType                 As Long
  uDhcpEnabled          As Long
  CurrentIpAddress      As Long
  IpAddressList         As IP_ADDR_STRING
  GatewayList           As IP_ADDR_STRING
  DhcpServer            As IP_ADDR_STRING
  bHaveWins             As Long
  PrimaryWinsServer     As IP_ADDR_STRING
  SecondaryWinsServer   As IP_ADDR_STRING
  LeaseObtained         As Long
  LeaseExpires          As Long
End Type

Private Declare Function GetAdaptersInfo Lib "iphlpapi.dll" _
  (pTcpTable As Any, _
   pdwSize As Long) As Long
   
Private Declare Sub CopyMemory Lib "kernel32" _
   Alias "RtlMoveMemory" _
  (dst As Any, _
   src As Any, _
   ByVal bcount As Long)
   

Private Sub Command1_Click()

  'pass a character to be used as the
  'delimiter in the list of returned addresses.
   Text1.Text = DhcpServerAddresses("+")

End Sub

   
Public Function DhcpServerAddresses(ByVal sDelim As String) As String

  'api vars
   Dim buff()      As Byte
   Dim cbRequired  As Long
   Dim Adapter     As IP_ADAPTER_INFO
   Dim AdapterStr  As IP_ADDR_STRING

  'working vars
   Dim ptr1        As Long
   Dim ptr2        As Long
   Dim sAllAddr    As String
   Dim sIPAddr     As String

   Call GetAdaptersInfo(ByVal 0&, cbRequired)

   If cbRequired > 0 Then

      ReDim buff(0 To cbRequired - 1) As Byte

      If GetAdaptersInfo(buff(0), cbRequired) = ERROR_SUCCESS Then

        'get a pointer to the data stored in buff()
         ptr1 = VarPtr(buff(0))

         Do While (ptr1 <> 0)

           'copy the data from the pointer to the
           'first adapter into the IP_ADAPTER_INFO type
            CopyMemory Adapter, ByVal ptr1, LenB(Adapter)

            With Adapter

               If .uDhcpEnabled = 1 Then

                 'the DHCP info is in the DhcpServer
                 'member of IP_ADAPTER_INFO. This is
                 'in the IP_ADDR_STRING format, so
                 'it needs to be copied to the
                 'IP_ADDR_STRING type
                  ptr2 = VarPtr(.DhcpServer)

                 'again, the IP_ADDR_STRING type has a
                 'dwNext member, indicating that more
                 'than one DHCP server may be listed,
                 'so another loop is needed
                  Do While (ptr2 <> 0)

                     CopyMemory AdapterStr, ByVal ptr2, LenB(AdapterStr)

                     With AdapterStr

                       'the IP address of the DHCP
                       'server for this adapter.
                        sIPAddr = TrimNull(StrConv(.IpAddress.IpAddr, vbUnicode))

                       'add to a string, separating with
                       'a null character, and continue
                       'until ptr2 is 0
                        sAllAddr = sAllAddr & sIPAddr & sDelim

                       'check for another server
                        ptr2 = .dwNext

                     End With  'With AdapterStr
                  Loop  'Do While (ptr2 <> 0)

               End If  'If .uDhcpEnabled

              'check for another adapter
               ptr1 = .dwNext

            End With  'With Adapter

        'keep in loop until ptr1 returns 0
        '(no more adapters)
         Loop  'While (ptr1 <> 0)

       'if a string was built, remove the last delimiter
         If Len(sAllAddr) > 0 Then
            sAllAddr = Left$(sAllAddr, Len(sAllAddr) - 1)
         End If

      End If  'If GetAdaptersInfo
   End If 'If cbRequired > 0

  'return any string found
   DhcpServerAddresses = sAllAddr
   
End Function


Private Function TrimNull(item As String)

    Dim pos As Integer
   
   'double check that there is a chr$(0) in the string
    pos = InStr(item, Chr$(0))
    If pos Then
       TrimNull = Left$(item, pos - 1)
    Else
       TrimNull = item
    End If
  
End Function