Visual Basic WMI System Services
Win32_Keyboard: WMI Keyboard Information
     
Posted:   Tuesday March 26, 2002
Updated:   Monday November 28, 2011
     
Applies to:   VB5, VB6
Developed with:   VB6, Windows XP
OS restrictions:   Windows NT, 2000, XP. See Prerequisites below.
Author:   VBnet - Randy Birch
     

Related:  

Win32_DesktopMonitor: WMI Desktop Monitor Info
Win32_DisplayConfiguration: WMI Display Configuration Info
Win32_VideoController: WMI Video Controller Info
     
 Prerequisites
Windows Script Host is built into Microsoft Windows 98, 2000, ME and XP. If you are running Windows 95 or NT4, you can download Windows Script Host from the Microsoft Windows Script Technologies Web site at http://msdn.microsoft.com/scripting/. Some information is not returned on non-NT-based systems.

A reference set in Projects / References to the Microsoft WMI Scripting Library.


Win32_Keyboard class represents a keyboard installed on a Windows system.

This demo and illustration only show some of the available information from the class. For a complete listing see the table in the Comments section below. Note that some systems may not return information in all class properties.

 BAS Module Code
None.

 Form Code
To a form add a command button (Command1) and a listview (Listview1). Set a reference in Projects / References to the Microsoft WMI Scripting Library, and add the following to the form:

Option Explicit
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Copyright 1996-2011 VBnet/Randy Birch, All Rights Reserved.
' Some pages may also contain other copyrights by the author.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Distribution: You can freely use this code in your own
'               applications, but you may not reproduce 
'               or publish this code on any web site,
'               online service, or distribute as source 
'               on any media without express permission.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'listview column auto-resizing
Private Const LVM_FIRST As Long = &H1000
Private Const LVM_SETCOLUMNWIDTH As Long = (LVM_FIRST + 30)
Private Const LVSCW_AUTOSIZE As Long = -1
Private Const LVSCW_AUTOSIZE_USEHEADER As Long = -2

Private Declare Function SendMessage Lib "user32" _
   Alias "SendMessageA" _
  (ByVal hwnd As Long, _
   ByVal wMsg As Long, _
   ByVal wParam As Long, _
   lParam As Any) As Long


Private Sub Form_Load()

   With ListView1
      .ListItems.Clear
      .ColumnHeaders.Clear
      .View = lvwReport
      .Sorted = False
   End With
   
   Command1.Caption = "Keyboard Info"
   
End Sub


Private Sub Command1_Click()

   ListView1.ListItems.Clear
   Call wmiKeyboardInfo
   Call lvAutosizeControl(ListView1)
   
End Sub


Private Sub lvAutosizeControl(lv As ListView)

   Dim col2adjust As Long

  'Size each column based on the maximum of
  'wither the ColumnHeader text width, or,
  'if the items below it are wider, the
  'widest list item in the column
   lv.Visible = False
   For col2adjust = 0 To lv.ColumnHeaders.Count - 1
   
      Call SendMessage(lv.hwnd, _
                       LVM_SETCOLUMNWIDTH, _
                       col2adjust, _
                       ByVal LVSCW_AUTOSIZE_USEHEADER)

   Next
   lv.Visible = True
   
End Sub


Private Sub wmiKeyboardInfo()

   Dim wmiObjSet  As SWbemObjectSet
   Dim obj        As SWbemObject
   Dim thiscol    As Long
   Dim itmx       As ListItem

   On Local Error Resume Next
   
  'add first column and set initial parameters
   With ListView1
      .ListItems.Clear
      .View = lvwReport
      .Sorted = False
      .ColumnHeaders.Clear
      .ColumnHeaders.Add , , "WMI Property"
      .ColumnHeaders.Add , , "Value"
      .ListItems.Add , , "Description"
      .ListItems.Add , , "Name"
      .ListItems.Add , , "Caption"
      .ListItems.Add , , "Status"
      .ListItems.Add , , "Availability"
      .ListItems.Add , , "Layout"
      .ListItems.Add , , "NumberOfFunctionKeys"
      .ListItems.Add , , "DeviceID"
      .ListItems.Add , , "PNPDeviceID"
   End With

   Set wmiObjSet = GetObject("winmgmts:{impersonationLevel=impersonate}"). _
                                        InstancesOf("Win32_Keyboard")
       
  'fill in data
   For Each obj In wmiObjSet
   
      With ListView1
         
         thiscol = (.ColumnHeaders.Count - 1)
         
         .ListItems(1).SubItems(thiscol) = obj.Description
         .ListItems(2).SubItems(thiscol) = obj.Name
         .ListItems(3).SubItems(thiscol) = obj.Caption
         .ListItems(4).SubItems(thiscol) = obj.Status
         .ListItems(5).SubItems(thiscol) = IIf(obj.Availability, obj.Availability, "null")
         .ListItems(6).SubItems(thiscol) = obj.Layout
         .ListItems(7).SubItems(thiscol) = obj.NumberOfFunctionKeys
         .ListItems(8).SubItems(thiscol) = obj.DeviceID
         .ListItems(9).SubItems(thiscol) = obj.PNPDeviceID

         
      End With
      
   Next
   
End Sub
 Comments
All information returned in the Win32_Keyboard class (note that some systems may not return information in all class properties):
   
uint16 Availability
string Caption
uint32 ConfigManagerErrorCode
boolean ConfigManagerUserConfig
string CreationClassName
string Description
string DeviceID
boolean ErrorCleared
string ErrorDescription
datetime InstallDate
boolean IsLocked
uint32 LastErrorCode
string Layout
string Name
uint16 NumberOfFunctionKeys
uint16 Password
string PNPDeviceID
uint16 PowerManagementCapabilities[]
boolean PowerManagementSupported
string Status
uint16 StatusInfo
string SystemCreationClassName
string SystemName

 
 

PayPal Link
Make payments with PayPal - it's fast, free and secure!

 
 
 
 

Copyright 1996-2011 VBnet and Randy Birch. All Rights Reserved.
Terms of Use  |  Your Privacy

 

Hit Counter