Private Sub Form_Load()

   Command1.Caption = "Load Controls"
   Command2.Caption = "Run Chkdsk"

End Sub


Private Sub Command1_Click()

  'enumerates through all fixed local
  'drives and creates a label and
  'checkbox for each available local drive
  
   Dim LogicalDiskSet As SWbemObjectSet
   Dim disk As SWbemObject
   Dim msg As String
   Dim ssql As String
   Dim cnt As Long
   Dim x As Long
   
   ssql = "select Name from Win32_LogicalDisk where DriveType=3"
   Set LogicalDiskSet = GetObject("winmgmts:{impersonationLevel=impersonate}").ExecQuery(ssql)
   
   For Each disk In LogicalDiskSet
   
     'create a checkbox and label
     'for each local fixed drive
     
     'since array elements(0) already
     'exists, don't try to load it
      If cnt > 0 Then
         Load Check1(cnt)
         Load Label1(cnt)
      End If
   
     'Position the new controls.
     'Since I hard-coded the offsets and I develop 
     'at 1280 with small fonts, the values below 
     'may need tweaking for systems with different 
     'settings to position and align the loaded controls.
      With Check1(cnt)
         .Move 240, 300 + (cnt * 360), 600
         .Caption = disk.Name
         .Enabled = True
         .Visible = True
         .Alignment = 1
         .Value = 0
      End With
      
      With Label1(cnt)
         .Move Check1(cnt).Left + Check1(cnt).Width + 100, 300 + (cnt * 360), 2500
         .AutoSize = True
         .Enabled = True
         .Visible = True
         .Caption = "not included"
      End With
      
      cnt = cnt + 1
   Next
   
  'prevent reloading of controls
   Command1.Enabled = False
   
  'clean up
   Set disk = Nothing
   Set LogicalDiskSet = Nothing
   
End Sub


Private Sub Command2_Click()

   Dim LogicalDiskSet As SWbemObjectSet
   Dim disk As SWbemObject
   Dim ssql As String
   Dim cnt As Long

  'return a reference to the fixed disks
   ssql = "select Name,FileSystem from Win32_LogicalDisk where DriveType=3"
   Set LogicalDiskSet = GetObject("winmgmts:{impersonationLevel=impersonate}").ExecQuery(ssql)

   If LogicalDiskSet.Count > 0 Then
      
     'loop through each returned disk
      For Each disk In LogicalDiskSet
                    
        'if the disk matched the
        'checkbox caption and the
        'checkbox was selected,
        'perform chkdsk against the drive
         If disk.Name = Check1(cnt).Caption And _
                        Check1(cnt).Value = 1 Then
            
           'since this can take a while
           'indicate process has started
            Label1(cnt).Caption = "Running chkdsk against drive " & _
                                  disk.Name & " ... please wait."
            Label1(cnt).Refresh
            
           'show result of call
            Label1(cnt).Caption = Chkdsk(disk) & "  (" & disk.FileSystem & ")"

         End If
         
         cnt = cnt + 1
         
      Next

   End If
   
  'clean up
   Set disk = Nothing
   Set LogicalDiskSet = Nothing

End Sub


Private Sub Check1_Click(Index As Integer)

   If Check1(Index).Value = 1 Then
      Label1(Index).Caption = "waiting to run command"
   Else
      Label1(Index).Caption = "not included"
   End If
   
End Sub


Private Function Chkdsk(disk As SWbemObject) As String

  'chkdsk method parameters:
  '----------------------------
  'FixErrors : boolean
  'Indicates what should be done to errors found
  ' on the disk. If true, then errors are fixed.
  'The default is FALSE.
  '
  'VigorousIndexCheck : boolean
  'If TRUE, a vigorous check of index
  'entries should be performed.
  'The default is TRUE.
  '
  'SkipFolderCycle : boolean
  'If TRUE, the folder cycle checking
  'should be skipped or not.
  'The default is TRUE.
  '
  'ForceDismount : boolean
  'If TRUE, the drive should be forced
  'to dismount before checking.
  'The default is FALSE.
  '
  'RecoverBadSectors : boolean
  'If TRUE, the bad sectors should be located
  'and the readable information should be
  'recovered from these sectors.
  'The default is FALSE.
  '
  'OKToRunAtBootUp : boolean
  'If TRUE, the chkdsk operation should
  'be performed at next boot up time, in
  'case the operation could not be performed
  'because the disk was locked at time
  'the method was called. The default is FALSE.

   Select Case disk.Chkdsk(False, True, True, False, False, False)
      Case 0: Chkdsk = "Success - chkdsk completed"
      Case 1: Chkdsk = "Success - Disk locked - chkdsk scheduled on reboot"
      Case 2: Chkdsk = "Unknown file system"
      Case 3: Chkdsk = "Unknown error"
   End Select

End Function