'/* Below used for listview column auto-resizing
Private Const LVM_FIRST As Long = &H1000
Private Const LVM_SETCOLUMNWIDTH As Long = (LVM_FIRST + 30)
Private Const LVSCW_AUTOSIZE As Long = -1
Private Const LVSCW_AUTOSIZE_USEHEADER As Long = -2

Private Declare Function SendMessage Lib "user32" _
   Alias "SendMessageA" _
  (ByVal hwnd As Long, _
   ByVal wMsg As Long, _
   ByVal wParam As Long, _
   lParam As Any) As Long


Private Sub Form_Load()

   With ListView1
      .ListItems.Clear
      .ColumnHeaders.Clear
      .ColumnHeaders.Add , , "DevID"
      .ColumnHeaders.Add , , "Avail"
      .ColumnHeaders.Add , , "AddrWd"
      .ColumnHeaders.Add , , "Status"
      .ColumnHeaders.Add , , "SpdNow"
      .ColumnHeaders.Add , , "SpdMax"
      .ColumnHeaders.Add , , "L2Siz"
      .ColumnHeaders.Add , , "L2Spd"
      .ColumnHeaders.Add , , "VoltCap"
      .ColumnHeaders.Add , , "Name"
      
      .View = lvwReport
      .Sorted = False
   End With
          
   Command1.Caption = "Get Adapter Info"

End Sub


Private Sub Command1_Click()

   ListView1.ListItems.Clear
   Call wmiProcessorInfo
   Call lvAutosizeControl(ListView1)
   
End Sub


Private Sub lvAutosizeControl(lv As ListView)

   Dim col2adjust As Long

  '/* Size each column based on the maximum of
  '/* EITHER the columnheader text width, or,
  '/* if the items below it are wider, the
  '/* widest list item in the column
   For col2adjust = 0 To lv.ColumnHeaders.Count - 1
   
      Call SendMessage(lv.hwnd, _
                       LVM_SETCOLUMNWIDTH, _
                       col2adjust, _
                       ByVal LVSCW_AUTOSIZE_USEHEADER)

   Next
   
End Sub


Private Sub wmiProcessorInfo()

   Dim cpuSet As SWbemObjectSet
   Dim cpu As SWbemObject
   Dim itmx As ListItem
   
   Set cpuSet = GetObject("winmgmts:{impersonationLevel=impersonate}"). _
                           InstancesOf("Win32_Processor")
    
   For Each cpu In cpuSet
   
      Set itmx = ListView1.ListItems.Add(, , cpu.DeviceID)
      itmx.SubItems(1) = cpu.Availability
      itmx.SubItems(2) = cpu.AddressWidth
      itmx.SubItems(3) = cpu.CpuStatus
      itmx.SubItems(4) = cpu.CurrentClockSpeed
      itmx.SubItems(5) = cpu.MaxClockSpeed
      itmx.SubItems(6) = cpu.L2CacheSize
      itmx.SubItems(7) = cpu.L2CacheSpeed
      itmx.SubItems(8) = cpu.VoltageCaps
      itmx.SubItems(9) = cpu.Name
        
   Next

End Sub