'/* Below used for listview column auto-resizing
Private Const LVM_FIRST As Long = &H1000
Private Const LVM_SETCOLUMNWIDTH As Long = (LVM_FIRST + 30)
Private Const LVSCW_AUTOSIZE As Long = -1
Private Const LVSCW_AUTOSIZE_USEHEADER As Long = -2

Private Declare Function SendMessage Lib "user32" _
   Alias "SendMessageA" _
  (ByVal hwnd As Long, _
   ByVal wMsg As Long, _
   ByVal wParam As Long, _
   lParam As Any) As Long


Private Sub Form_Load()

   With ListView1
      .ListItems.Clear
      .ColumnHeaders.Clear
      .ColumnHeaders.Add , , "Desc"
      .ColumnHeaders.Add , , "Name"
      .ColumnHeaders.Add , , "Device ID"
      .ColumnHeaders.Add , , "Status"
      .ColumnHeaders.Add , , "Resolution"
      .ColumnHeaders.Add , , "Tolerance"
      .ColumnHeaders.Add , , "Accuracy"
      .View = lvwReport
      .Sorted = False
   End With
   
   Command1.Caption = "Temperature Probe Info"
   
End Sub


Private Sub Command1_Click()

   ListView1.ListItems.Clear
   Call wmiProbeInfo
   Call lvAutosizeControl(ListView1)
   
End Sub


Private Sub lvAutosizeControl(lv As ListView)

   Dim col2adjust As Long

  '/* Size each column based on the maximum of
  '/* EITHER the columnheader text width, or,
  '/* if the items below it are wider, the
  '/* widest list item in the column
   For col2adjust = 0 To lv.ColumnHeaders.Count - 1
   
      Call SendMessage(lv.hwnd, _
                       LVM_SETCOLUMNWIDTH, _
                       col2adjust, _
                       ByVal LVSCW_AUTOSIZE_USEHEADER)

   Next
   
End Sub


Private Sub wmiProbeInfo()

   Dim wmiObjSet As SWbemObjectSet
   Dim obj As SWbemObject   'CurrentProbe
   Dim itmx As ListItem

   On Local Error Resume Next
   Set wmiObjSet = GetObject("winmgmts:{impersonationLevel=impersonate}"). _
                              InstancesOf("Win32_TemperatureProbe")
    
   For Each obj In wmiObjSet
    
      Set itmx = ListView1.ListItems.Add(, , obj.Description)
      itmx.SubItems(1) = obj.Name
      itmx.SubItems(2) = obj.DeviceID
      itmx.SubItems(3) = obj.Status
      itmx.SubItems(4) = obj.Resolution
      itmx.SubItems(5) = obj.Tolerance
      itmx.SubItems(6) = obj.Accuracy / obj.Resolution / obj.Tolerance & " %"
   Next
   
End Sub